Error – j.a.estevan

[AX TIP] Errores Interop CLR y nivel de transacciones

Hace un tiempo publiqué un artículo explicando las buenas prácticas recomendadas para el manejo de excepciones CLR y cómo mostrarlas correctamente en el InfoLog de Dynamics AX. Sin embargo olvidé entonces un detalle importante que hay que tener en cuenta al capturar estas excepciones, que es el nivel de transacciones en la base de datos (TTS Level). En el siguiente código de ejemplo, nuestro try..catch NO funcionará. Si se produce un error en el try, por ejemplo, si el método get_Content() no existe en el objeto en tiempo de ejecución, la ejecución del código terminará directamente sin mostrar nada en el InfoLog, lo que no es muy deseable. Esto es debido a que, para poder capturar una excepción CLR, el nivel de transacciones debe ser 0. O lo que es lo mismo, no podemos capturar errores del Interop dentro de una transacción. Para que este código funcione tendremos que re-escribirlo para que el manejo de ese objeto CLR genérico se realice antes de abrir la transacción.

CLRObject 		obj;
 
 
ttsBegin;  // ttsLevel + 1
 
info(strFmt("TTS level: %1", appl.ttsLevel())); // TTS level: 1
 
try
{
	obj = response.get_Content();
	if (!CLRInterop::isNull(obj))
	{
		// ...
	}
}
catch(Exception::CLRError) // Este catch nunca se ejecutará porque ttsLevel > 0
{
	error(AifUtil::getClrErrorMessage());
}
 
ttsCommit; // ttsLevel - 1

En realidad, y debido al alto riesgo de que se produzcan errores CLR que deben capturarse y procesarse de forma especial, el manejo de objetos CLR debe encapsularse siempre en clases o métodos específicos donde quede claro su funcionamiento y aislado el riesgo de problemas.

Errores Interop CLR y manejo de Infolog en Microsoft Dynamics AX 2012

Al trabajar con objetos del framework .NET (algo muy común en AX 2012), debemos tener en cuenta el tratamiento de errores CLR. El tratamiento de errores en Dynamics AX es transparente y no necesita dedicarle demasiada atención durante el desarrollo en X++, pero cuando interviene el Interop con .NET, el manejo de los errores CLR se debe especificar de forma explícita. El código que suelo utilizar habitualmente (copiado y pegado de mi repositorio personal) como punto de inicio es el siguiente:

static void JAEE_CLRError(Args _args) 
{ 
    System.Exception ex;
 
    new InteropPermission(InteropKind::ClrInterop).assert();  
 
    try 
    { 
        System.Int32::Parse("JAEE");  // Error: no se puede convertir un texto a Int32
    } 
    catch (Exception::CLRError)
    {
        ex = ClrInterop::getLastException();
        if (ex != null) 
        {
            info(ex.get_Message());
            ex = ex.get_InnerException();
            if (ex != null)
                error(ex.ToString());
        }
    }    
    catch (Exception::Internal)
    {
        ex = ClrInterop::getLastException();
        if (ex != null) 
            info(ex.get_Message());
    }   
 
    CodeAccessPermission::revertAssert(); 
}

Tag: Error

[AX TIP] Errores Interop CLR y nivel de transacciones

Errores Interop CLR y manejo de Infolog en Microsoft Dynamics AX 2012